ChadSmiley Blog :: Edit Document Fields 5.1.1 Code

Bookmark :
Edit Document Fields 5.1.1 Code

Select All
REM {Edit Document Fields 5.1.1 by Chad Schelfhout.};
REM {Visit http://www.chadsmiley.com/EditDocumentFields for the latest updates};

REM {Constants};
EditLastField := "edfLastField";
EditLastFieldDataType := "edfLastFieldDataType";
EditLastSeparator := "%~%";
SemicolonReplace := "#SC#";
ProfileName := "ChadSmiley Tools";
PromptTitle := @DbTitle + " - " + @ViewTitle;
MaxSearchForSelectedDocs := 5520;
MaxUpdatedDocuments := 1000;
Arrayseparator := ";";
NoteEntryLength := 11;
PormptNewLine := @Char(13) + @Char(13);
CategoryNoteID := "NT00000000";

REM {Data types|@Function execution};
DataTypesCombo := @Explode(
"Integer|@TextToNumber( RawValue )$"+
"Integer Multi Value|@TextToNumber( @Explode( RawValue ; Separator; @True) )$"+
"Date|@ToTime( RawValue )$"+
"Date Multi Value|@ToTime( @Explode( RawValue ; Separator; @True) )$"+
"Text|@Text( RawValue )$"+
"Text Multi Value|@Text( @Explode( RawValue ; Separator; @True) )$"+
"Text Left|@Left( @Text( @GetField( EditField[ef] ) ) ; ExtractValue )$"+
"Text Left Back|@LeftBack( @Text( @GetField( EditField[ef] ) ) ; ExtractValue )$"+
"Text Right|@Right( @Text( @GetField( EditField[ef] ) ) ; ExtractValue )$"+
"Text Right Back|@RightBack( @Text( @GetField( EditField[ef] ) ) ; ExtractValue )$"+
"Name|RawValue$"+
"Name Multi Value|RawValue$"+
"Common Name|@Name( [CN]; RawValue )$"+
"CommonName Multi Value|@Name( [CN]; @Explode( RawValue ; \":\"; @True ) )$"+
"Upper Case Text|@UpperCase( @Implode( @Text( @GetField( EditField[ef] ) ) ) )$"+
"Lower Case Text|@LowerCase( @Implode( @Text( @GetField( EditField[ef] ) ) ) )$"+
"Proper Case Text|@ProperCase( @Implode( @Text( @GetField( EditField[ef] ) ) ) )$"+
"Upper Case Text Multi Value|@UpperCase( @Explode( @Text( @GetField( EditField[ef] ) ) ; Separator; @True ))$"+
"Lower Case Text Multi Value|@LowerCase( @Explode( @Text( @GetField( EditField[ef] ) ) ; Separator; @True) )$"+
"Proper Case Text Multi Value|@ProperCase( @Explode( @Text( @GetField( EditField[ef] ) ) ; Separator; @True) )$"+
"Replace Substring|@ReplaceSubstring( @GetField( EditField[ef] ); FromRawValue ; RawValue )$"+
"Replace|@Explode( @Replace( @GetField( EditField[ef] ) ; FromRawValue ; RawValue ) ; Separator ; @True )$"+
"Implode|@Implode( @Text( @GetField( EditField[ef] ) ) ; Separator )$"+
"Explode|@Explode( @Text( @GetField( EditField[ef] ) ) ; Separator; @True )$"+
"Formula|@Eval( RawValue )$"+
"Abbreviate Name|@Name([Abbreviate]; RawValue )$"+
"Abbreviate Name Multi Value|@Name( [Abbreviate]; @Explode( RawValue ; Separator; @True ) )$"+
"Password Set|@Password( RawValue )$"+
"Password Convert|@Password( @GetField( EditField[ef] ) )$"+
"Remove Field|@DeleteField$"+
"Unique|@Unique(@GetField( EditField[ef]))$"+
"+ Append Values|@If(" +
" 				@GetField(EditField[ef]) = \"\"; RawValue;" +
" 				@Contains(DefaultDataType; \"Date\");" +
" 					@If( @IsError( @ToTime( RawValue ) ) ;" +
" 						\"\" ;" +
" 						@SetField( EditField[ef] ; @GetField(EditField[ef]) : @TextToTime( @Explode( RawValue ; Separator ) ) ) ) ;" +
" 				@Contains(DefaultDataType; \"Integer\" );" +
" 					@If( @IsError( @TextToNumber( @Explode( RawValue ; Separator ) ) ) ;" +
" 						\"\" ;" +
" 						@SetField( EditField[ef] ; @GetField(EditField[ef]) : @TextToNumber( @Explode( RawValue ; Separator ) ) ) ) ;" +
" 				@SetField( EditField[ef] ; @GetField(EditField[ef]) : @Explode( RawValue ; Separator ) ) )$"+
"Sort Ascending|@Sort(@GetField(EditField[ef]) ; [Ascending] )$"+
"Sort Descending|@Sort(@GetField(EditField[ef]); [Descending])" ; "$" );

DataTypes := @Word( DataTypesCombo ; "|" ; 1 );
DataTypesAction := @Word( DataTypesCombo ; "|" ; 2 );

REM {Get a listing of all the fields on the current document};
List := @Sort( @DocFields );

REM {Look for last field modified in Profile Doc};
FieldList := @Explode( @GetProfileField( ProfileName ; EditLastField ; @UserName ) ; Arrayseparator ; @True ) ;

REM {Get the list of forms and field that was updated using Edit Document Fields};
FieldListForms := @Word( FieldList ; EditLastSeparator ; 1 );
FieldListField := @Word( FieldList ; EditLastSeparator ; 2 );
FieldListLastIndex := @Member( Form; FieldListForms );
REM {If the FieldListLastIndex is greater than zero then set the last field to the what was in the profile document};
@If( FieldListLastIndex > 0;
	@Do( LastField := FieldListField[ FieldListLastIndex ];
		FieldList := @ReplaceSubstring( FieldList ; FieldList[ FieldListLastIndex ] ; "" ) );
	LastField :="" );

REM {Prompt for which field needs to be updated. Loop until a field is selected or 'Cancel' is selected};
@DoWhile(
	EditField := @Prompt( [OkCancelEditCombo] ; PromptTitle ; "Select the field you wish to alter or enter a new field to add:" ; LastField ; @Trim( @Unique( List : LastField ) ) );
	EditField = "" );
EditFieldPromptTitle := EditField + " - " + PromptTitle;

REM {This will allow the retrieval of the data type of the field that was last selected. Data is stored like Form+Field%~%DataType.};
FormFieldList := @Explode( @GetProfileField( ProfileName ; EditLastFieldDataType ; @UserName ) ; Arrayseparator ; @True ) ;
FormFieldListFormField := @Word( FormFieldList ; EditLastSeparator ; 1 );
FormFieldListDataType := @Word( FormFieldList ; EditLastSeparator ; 2 );
FormFieldListFormulaCode := @ReplaceSubstring( @Word( FormFieldList ; EditLastSeparator ; 3 ) ; SemicolonReplace ; ";" );
FormFieldListIndex := @Member( Form + EditField; FormFieldListFormField );
@If( FormFieldListIndex > 0;
	@Do( DefaultDataType := FormFieldListDataType[ FormFieldListIndex ];
		FormFieldListFormulaCode := FormFieldListFormulaCode[ FormFieldListIndex ];
		FormFieldList := @ReplaceSubstring( FormFieldList ; FormFieldList[ FormFieldListIndex ] ; "" ) );
	DefaultDataType :="" );

REM {If there was no data type used for the field on the form the try to determine the data type};
DefaultDataType :=
	@If( DefaultDataType != "" ;
		DefaultDataType ;
		@If(
			@IsNumber( @GetField( EditField ) ) ;
				@If( @Count( @GetField( EditField ) ) > 1 ;
					"Integer Multi Value" ;
					"Integer" ) ;
			@IsTime( @GetField( EditField ) ) ;
				@If( @Count( @GetField( EditField ) ) > 1 ;
					"Date Mult iValue" ;
					"Date" ) ;
			@If( @Count( @GetField( EditField ) ) > 1 ;
					"Text Multi Value" ;
					"Text" )
			)
	);

REM {If the data type is a type of error then select the data type of text};
DefaultDataType := @IfError( DefaultDataType ; "Text" );

REM {Prompt for which data type you would like the data to be. This needs to be done before value prompt to determine if the Picklist or any prompting needs to be used.};
DataType := @Prompt( [OkCancelList] ; EditFieldPromptTitle; "Please select the correct data type or action for field: " + EditField + "."; DefaultDataType ; DataTypes );

REM {The DataTypeAction will contain the formula that will be executed to retrieve the new value};
DataTypeAction := DataTypesAction[ @Member( DataType ; DataTypes ) ];

REM {If formula was used on this field then use that instead of the fields value. Format the original value as text because the @Prompt command requires text.};
OriginalValue := @If( DataType = "Formula" & DefaultDataType = "Formula" & FormFieldListFormulaCode != "" ;
	FormFieldListFormulaCode ;
	@If( @Contains( DefaultDataType ; MultiValue ) ;
		@Implode( @Text( @GetField( EditField ) ) ; Arrayseparator );
		@Text( @GetField( EditField ) ) )
	);

REM {Prompt for additional fields and determine the string that they are searching for.};
@If( DataType = ("Replace Substring":"Replace" ) ;
	@Do( EditField := @Unique( EditField : @Prompt( [OkCancelListMult] ; PromptTitle ; "Select any addtional fields you wish to alter:" ; EditField ; List ) );
		FromRawValue := @Prompt( [OkCancelEdit] ; EditFieldPromptTitle ; "Please enter the text (Case sensitive) to search for in: " + @Implode( EditField ; ", " ) + "." ; "" ) );
	@Do( EditField := EditField;
		FromRawValue := "" )
	);

Separator := @If( DataType = ("Implode":"Explode" ) ;
	@Prompt( [OkCancelEdit] ; PromptTitle ; "Enter the " + @If( DataType = "Implode" ; "separator" ; "separators" ) + Arrayseparator ; "" );
	Arrayseparator );

ExtractValue := @If( DataType = ("Text Left":"Text Left Back":"Text Right":"Text Right Back" ) ;
	@Prompt( [OkCancelEdit] ; PromptTitle ; "Enter the search string:" ; "" );
	"" );

REM {Based on what type of data is being entered different prompts will happen if any at all.};
RawValue := @If(
	@Contains( DataType ; "Name Multi Value" ) ; @PickList( [Name] );
	@Contains( DataType ; "Name" ) ; @PickList( [Name] : [Single] );
	DataType = ( "Remove Field":"Unique":"Sort Ascending":"Sort Descending":"Implode":"Explode":"Proper Case Text":"Proper Case Text Multi Value":"Lower Case Text":"Lower Case Text Multi Value":"Upper Case Text":"Upper Case Text Multi Value":"Password Convert":"Text Left":"Text Left Back":"Text Right":"Text Right Back" ) ; "" ;
	@Contains( DataType ; "Multi Value" ) ; @Prompt( [OkCancelEdit] ; EditFieldPromptTitle; "Please enter the new desired value for: " + @Implode( EditField ; ", " ) + "." + PormptNewLine + "Seperated with ; for each value." ; OriginalValue ) ;
	@Contains( DataType ; "+ Append Values" ) ; @Prompt( [OkCancelEdit] ; EditFieldPromptTitle; "Please enter values to append: " + @Implode( EditField ; ", " ) + "." + PormptNewLine + "Seperated with ; for each value." ; "" ) ;
	DataType = ("Replace Substring":"Replace" ) ; @Prompt( [OkCancelEdit] ; EditFieldPromptTitle ; "Please enter the text to repalce with in: " + EditField + "." ; "" ) ;
	DataType = "Formula" ; @Do( @DoWhile(
		OriginalValue := @Prompt( [OkCancelEdit] ; EditFieldPromptTitle ; "Please enter the new desired formula for: " + EditField + "." ; OriginalValue ) ;
		tempReturnCheck := @CheckFormulaSyntax( OriginalValue );
		@If( tempReturnCheck != "1"; @Prompt( [Ok] ; "Invalid Formula" ; @Text( tempReturnCheck ) ) ; "" );
	tempReturnCheck != "1" );
	OriginalValue );
	@Prompt( [OkCancelEdit] ; EditFieldPromptTitle ; "Please enter the new desired value for: " + EditField + "." ; OriginalValue )
	);

REM {Store Field in Profile doc};
@SetProfileField( ProfileName ; EditLastField ; @Unique( @Trim( FieldList : ( Form + EditLastSeparator + EditField[1] ) ) ); @UserName );

REM {Store Data Type of Field in Profile doc};
@SetProfileField( ProfileName ; EditLastFieldDataType ; @Unique( @Trim( FormFieldList : ( Form + EditField[1] + EditLastSeparator + DataType + EditLastSeparator + @ReplaceSubstring( @If( DataType = "Formula" ; RawValue ; FormFieldListFormulaCode )  ; ";" ; SemicolonReplace ) )  ) ) ; @UserName );

REM {If multi docs selected, only process those checked ... an unchecked doc cannot be NavNextSelected};
@Command([NavNextSelected]);
@UpdateFormulaContext;

REM {Store all Note IDs before manipulation in case field modifications cause categorized views or sorted columns to reorganize};
NoteIDList := @Text( @NoteID );
@Command([NavNextSelected]);
@UpdateFormulaContext;

REM {Start Looping Selected documents};
@While( ( @Left( NoteIDList ; NoteEntryLength ) != ( @Text( @NoteID + Arrayseparator ) ) ) & ( @Length( NoteIDList ) < MaxSearchForSelectedDocs ) ;
	NoteIDList := NoteIDList + Arrayseparator + @Text( @NoteID );
	NoteIDList := @ReplaceSubstring( NoteIDList ; CategoryNoteID + Arrayseparator ; "" );
	@Command([NavNextSelected]);
	@UpdateFormulaContext
);

NoteIDList := @ReplaceSubstring( NoteIDList ; CategoryNoteID ; "" );
NoteIDList := @Unique( @Explode( NoteIDList ; Arrayseparator ; @False ) );
@StatusBar( "Found " + @Text( @Elements( NoteIDList ) ) + " documents." );
NotNoteIDList := "";

REM {Loop through selected docs taking each NoteIDList out of the list as it is processed};
DocUpdateCount := 0;
DocNavigationCount := 0;
@While( DocUpdateCount < @Elements( NoteIDList ) ;

	@If( @TextToNumber( @Text( @DocumentUniqueID ) ) != 0 ;
		@Do(
			NoteIDList := @Replace( NoteIDList ; @NoteID ; "" ) ;
			NotNoteIDList := NotNoteIDList : @NoteID;
			@For( ef := 1; ef <= @Elements( EditField ); ef := ef + 1;
				formulaResult := @Eval( DataTypeAction );
remark := " **REM** The values entered above will be applied to all selected doc. If data conversion doesn't work then don't set field.";
				@If( @IsError( formulaResult );
					@Return( @Prompt( [Ok] ;"Error" ; @Text( FormulaResult ) ) );
				@SetField( EditField[ef] ; formulaResult )
				)
			);
			@If( DocNavigationCount > MaxUpdatedDocuments ;
				 NoteIDList := "";
				@Do(
					DocUpdateCount := DocUpdateCount + 1;
					@Command([NavNextSelected]);
					@UpdateFormulaContext;
remark := " **REM** If we haven't processed all docs yet but the current doc is not in the NoteIDList list, keep looping ... if cnt exceeds MaxUpdatedDocuments assume infinite loop and stop ";
					@If( DocUpdateCount < @Elements( NoteIDList ) & ( !@Member( @NoteID ; NoteIDList ) ) & ( !@Member( @NoteID ; NotNoteIDList) );
						@While( (! @Member( @NoteID ; NoteIDList ) & DocNavigationCount < MaxUpdatedDocuments );
							@Command([NavNextSelected]);
							@UpdateFormulaContext;
							DocNavigationCount := DocNavigationCount + 1);
					"")
				)
			)
		);
	@Do( @Command([NavNextSelected]);
		@UpdateFormulaContext )
	)
);

@If( @Implode( @Unique( @Explode( NoteIDList ; Arrayseparator ; @False ) ) ) != "" ; @StatusBar( "Unable to update the following documents: " + @Implode( @Unique( @Explode( NoteIDList ; Arrayseparator ; @False ) ) ; ", " ) + "." ); "" );
@StatusBar( "Navigated through " + @Text( DocUpdateCount + DocNavigationCount ) + " documents." );
@StatusBar( "Performed '" + DataType + "' for '" + @Implode( EditField ; ", " ) + "' field" + @If( @Elements( EditField ) > 1; "s " ; " " ) + "on " + @Text( DocUpdateCount ) + " document" + @If( DocUpdateCount > 1 ; "s" ; "" ) + "." )
Permalink | Comments (0) | TrackBacks (0) | Category
ChadSmiley Blog

Things about family, life, coding, and more

Links

Latest Downloads

Twitter

Search

Albums

Ads by Google

Category

MiscLinks

Archive

Googles

02/27/2006

Edit Document Fields 5.1.1 Code

Edit Document Fields 5.1.1 Code
