ChadSmiley Blog :: Toolbar Functions 1.2.0

Bookmark :

There are a couple of new functions and a screencast explaining all of the functions. The new functions are indicated below. There is also history for Get and Set Environment Variables, Agent Run, Edit Profile Document, and Formula Evaluate. The history was built on some new features in Edit Document Fields.

Here are the current options:

Agent Run
Agent Run Current
Database Path
Database Replica ID
Database Server
Database Server & Path
Edit Profile Document
Formula Evaluate
Get Environment Value
Link Message
Note ID
Parent UNID
Refresh Selected Documents
Set Environment Value
Undo Replication Conflict
Unlock Document
UNID
Workflow Formula Test

Toolbar Functions 1.2.0 Code

Select All

REM {Toolbar Functions by Chad Schelfhout.};
REM {Visit http://www.chadsmiley.com/ToolbarFunctions for the latest updates};
REM {Version 1.2.0};

REM {Constants};
ProfileName := "ChadSmiley Tools";
ToolbarToolsLastSelection := "ToolbarToolsLastSelection";
ToolbarToolsLastProfile := "ToolbarToolsLastProfile";
ToolbarToolsLastEnvironmentVariable := "ToolbarToolsLastEnvironmentVariable";
ToolbarToolsLastFormula := "ToolbarToolsLastFormula";
DefaultSelection := "Undo Replication Conflict";
cSemicolonReplace := "#SC#";

REM {Get last selection for this database};
ToolbarToolsSelection := @GetProfileField( ProfileName ; ToolbarToolsLastSelection ; @UserName ) ;

Option := @Prompt( [OkCancelCombo] ; "Select Option" ; "What would you like to do:" ; @If( ToolbarToolsSelection = "" ; DefaultSelection ; ToolbarToolsSelection ) ; @Explode( "Undo Replication Conflict:Unlock Document:Refresh Selected Documents:Link Message:Workflow Formula Test:Agent Run:Agent Run Current:Note ID:UNID:Parent UNID:Database Replica ID:Database Path:Database Server:Database Server & Path:Edit Profile Document:Get Environment Value:Set Environment Value:Formula Evaluate"  ; ":" ) ) ;

REM {Set last selection for this database};
@SetProfileField( ProfileName ; ToolbarToolsLastSelection ; Option ; @UserName ) ;

@If( Option = "Refresh Selected Documents" ; @Command([ToolsRefreshSelectedDocs])  ; "") ;

@If( Option = "Undo Replication Conflict" ; @Do( @SetField("$REF" ; @DeleteField ) : @SetField( "$Conflict" ; @DeleteField ) ) ;

Option = "Unlock Document" ; @Do( @SetField("$Writers" ; @DeleteField ) : @SetField("$PWriters" ; @DeleteField ) : @SetField( "$WritersDate" ; @DeleteField ) ) ;

Option = "Agent Run" ; @Do ( @Command([RunAgent] ; @Prompt( [OkCancelEdit];"Run Agent" ; "Enter agent to run"; "" ) ) ) ;

Option = "Agent Run Current" ; @Do ( @Command([ToolsRunMacro]; $Title) ) ;

Option = "Link Message" ; @Do ( @Command([Compose]; @MailDbName; "Bookmark") ) ;

Option = "Edit Profile Document" ; @Do (
	@SetProfileField( ProfileName ; ToolbarToolsLastProfile ;
		@Trim(
			@Unique(
				@Prompt([OkCancelEditCombo];
					"Open Profile Document";
					"Profile Document Name (There should be a corresponding form or suborm)";
					@Subset( @Explode( @GetProfileField( ProfileName ; ToolbarToolsLastProfile ; @UserName ) ; ";" ) ;1 ) ;
					@Explode( @GetProfileField( ProfileName ; ToolbarToolsLastProfile ; @UserName ) ; ";" ) ) :
				@GetProfileField( ProfileName ; ToolbarToolsLastProfile ; @UserName ) ) );
		@UserName ) ;
	@Command([EditProfile] ;
		@Text( @Subset( @Explode( @GetProfileField( ProfileName ; ToolbarToolsLastProfile ; @UserName ) ; ";" ) ;1 )  ) ;
		@If( @Prompt( [YesNo] ; "Personal Profile" ; "Is '" + @Subset( @Explode( @GetProfileField( ProfileName ; ToolbarToolsLastProfile ; @UserName ) ; ";" ) ;1 ) + "' a personal profile?" ) ; @UserName ; "" ) ) );

Option = "Get Environment Value" ; @Do (
	CurrentEnvVariable := @GetProfileField( ProfileName ; ToolbarToolsLastEnvironmentVariable ; @UserName ) ) :
	@Set( "NewEnvVariable" ; @Prompt([OkCancelEditCombo]; "Get Environment Value"; "Enter the name of the environment variable:"; @Subset( CurrentEnvVariable ; 1 ); CurrentEnvVariable ) ) :
	@SetProfileField( ProfileName ; ToolbarToolsLastEnvironmentVariable ; @Trim( @Unique( NewEnvVariable : CurrentEnvVariable ) ); @UserName ) :
	@Prompt([OkCancelEdit]; "Environment Value"; "The value of the evironment variable '" + NewEnvVariable +  "':"  ;  @Environment( NewEnvVariable ) );

Option = "Set Environment Value" ; @Do (
	CurrentEnvVariable := @GetProfileField( ProfileName ; ToolbarToolsLastEnvironmentVariable ; @UserName ) ) :
	@Set( "NewEnvVariable" ; @Prompt([OkCancelEditCombo]; "Set Environment Value"; "Enter the name of the environment variable:"; @Subset( CurrentEnvVariable ; 1 ); CurrentEnvVariable ) ) :
	@SetProfileField( ProfileName ; ToolbarToolsLastEnvironmentVariable ; @Trim( @Unique( NewEnvVariable : CurrentEnvVariable ) ); @UserName ) :
	@SetEnvironment( NewEnvVariable ; @Prompt([OkCancelEdit]; "Environment Value"; "The new value of the evironment variable '" + NewEnvVariable +  "':"  ;  @Environment( NewEnvVariable ) ) );

Option = "Parent UNID" ; @Do ( @Prompt([OkCancelEdit]; "Parent UNID"; "Parent Unique ID"; @Text($REF)) ) ;

Option = "UNID" ; @Do ( @Prompt([OkCancelEdit]; "UNID"; "Unique ID"; @Text(@DocumentUniqueID)) ) ;

Option = "Database Replica ID" ; @Do ( @Prompt([OkCancelEdit]; "Database Replica ID"; "Database Replica ID"; @Text(@ReplicaID))  ) ;

Option = "Database Path" ; @Do ( @Prompt([OkCancelEdit]; "Database Path"; "Database Path"; @Text(@Subset( @DbName ; -1 ) ) )  ) ;

Option = "Database Server" ; @Do ( @Prompt([OkCancelEdit]; "Database Server"; "Database Server"; @Text(@Subset( @DbName ; 1 ) ) )  ) ;

Option = "Database Server & Path" ; @Do ( @Prompt([OkCancelEdit]; "Database Server & Path"; "Database Server & Path"; @Text( @Implode( @DbName ; "!!" ) ) )  ) ;

Option = "Note ID" ; @Do ( @Prompt([OkCancelEdit]; "Note ID"; "Note ID"; @Text(@NoteID))  ) ;

Option = "Formula Evaluate" ; @Do (
	CurrentForumla := @GetProfileField( ProfileName ; ToolbarToolsLastFormula ; @UserName ) ) :
	@Set( "NewFormula" ;
		@Prompt([OkCancelEditCombo];
			"Formula to Evaluate";
			"Enter the formula to evaluate:";
			@ReplaceSubstring( @Subset( CurrentForumla ; 1 ) ; cSemicolonReplace ; ";" );
			@ReplaceSubstring( CurrentForumla ; cSemicolonReplace ; ";" ) ) ) :
	@SetProfileField( ProfileName ;
		ToolbarToolsLastFormula ;
		@Trim( @Unique(  @ReplaceSubstring( NewFormula ; ";" ; cSemicolonReplace ) : CurrentForumla ) ); @UserName ) :
	@Prompt([OkCancelEdit]; "Formula Evaluated"; "The evaluate result:"  ; @Implode( @Text( @Eval ( NewFormula ) ) ) );

Option = "Workflow Formula Test" ; @Do ( @Command([Compose]; @DbName; "(OS FormulaTest)") ) ;

"" )

Comments

1 - And here is an improved version, that handles non-standard ports and SSL:
host:=@DbLookup("":""; @Subset(@DbName; 1) : "names.nsf"; "($Servers)"; @Subset(@DbName; 1); "SMTPFullHostDomain");
normalMode:=@DbLookup("":""; @Subset(@DbName; 1) : "names.nsf"; "($Servers)"; @Subset(@DbName; 1); "HTTP_NormalMode");
sslMode:=@DbLookup("":""; @Subset(@DbName; 1) : "names.nsf"; "($Servers)"; @Subset(@DbName; 1); "HTTP_SSLMode");
port:=@DbLookup("":""; @Subset(@DbName; 1) : "names.nsf"; "($Servers)"; @Subset(@DbName; 1); "HTTP_Port");
sslPort:=@DbLookup("":""; @Subset(@DbName; 1) : "names.nsf"; "($Servers)"; @Subset(@DbName; 1); "HTTP_SSLPort");

prefix:=@If(
normalMode = "1" | normalMode = "2"; "http";
"https"
);

portSuffix:=@If(
prefix = "http" & port = 80; "";
prefix = "https" & sslPort = "443"; "";
prefix = "http"; ":" + @Text(port);
prefix = "https"; ":" + @Text(sslPort);
""
);

@URLOpen(prefix + "://" + host + portSuffix + "/" + @WebDbName + "/0/" + @Text(@DocumentUniqueID) + "?OpenDocument")

Posted by Johan KÃ¤nngÃ¥rd At 06:31:21 AM On 12/01/2006 | - Website - |

2 - I love easy requests, done.

Posted by Chad Schelfhout At 05:40:49 AM On 11/15/2006 | - Website - |

3 - Tip: put the version number in your first REM statements in the code, so I know what version I have

Posted by Johan KÃ¤nngÃ¥rd At 07:16:45 AM On 11/14/2006 | - Website - |

4 - Thanks Johan. This is great.

Posted by Chad Schelfhout At 07:04:21 AM On 12/01/2006 | - Website - |

5 - Here is another request! A button to open the current document in a web browser. Here is a working contribution:
lookup:=@DbLookup("":""; @SubSet(@DbName; 1) : "names.nsf"; "($Servers)"; @SubSet(@DbName; 1); "SMTPFullHostDomain");
@If(
@IsError(lookup); @Prompt([OK]; "Invalid host name"; "Could not get host name from server document");
@URLOpen("{ Link } + lookup + "/" + @WebDbName + "/0/" + @Text(@DocumentUniqueID) + "?OpenDocument")
)

Posted by Johan KÃ¤nngÃ¥rd At 05:50:44 AM On 12/01/2006 | - Website - |