ChadSmiley Blog

1 - I often use the following very simple smarticon code to do updates to documents.

@Eval(@Prompt([OkCancelEdit]; "Formula Document Update"; "Please enter the formula to evaluate against the currently highlighted document"; ""))

I can then enter things like this into the prompt box

FIELD dateCreated := @Now; FIELD Creator := @Username; FIELD Subject := @ProperCase(Subject) + " plus extra subject text"

Which allows multiple fields to be updated, with a lot of flexibility of how the field updates are done. Perhaps this could be another option for your code? In other words, allow the user to enter a formula without specifying a field name or field value, and let the user supplied formula do all the work.

2 - Incredible piece of code, and I learnt a lot from it. But there was one bit I did not understand. If a name multi value, or common name multi value or abbreviated name multi value option is selected then the user is prompted with @PickList([Name]). As far as I am aware this returns a multivalued list rather than a delimited string. In other words, it does not need to be exploded to generate a list as it is already a list. This seems to be taken into account for the name multi value option because the formula for this option does not include an explode. But for the common and abbreviated name multi value options the value is exploded on the colon character which seems strange.

I removed the explode from these two lines with no apparent change in the way it works

"CommonName Multi Value|@Name( [CN]; RawValue )$"

"Abbreviate Name Multi Value|@Name( [Abbreviate]; RawValue )$"

Great piece of work Chad!! Many thanks for sharing this.

3 - Joel- Yes a simple form would work, but what is nice about this code is it all encompassing. All you have to do is add the code to a toolbar icon. There are other field editors out there that have some of these features. Here is one the Joe Litton did using LS: http://joelitton.net/A559B2/home.nsf/plinks/JLIN-6FS498

4 - Wow, you've really taken the edit fields SmartIcon idea to the Nth degree. Nice work.

I've a couple of suggestions, and I'd like to pass along [below] my copy of the code (not nearly as fully featured as yours) to see if it offers any ideas. I hope this form permits this much text.

1. Would it be possible to add the ability to set a field to the Authors or Readers attribute?

2. It's a wonderful help for the macro to show the current contents of the field, allowing one to edit that. Perhaps this doesn't fit nicecly within the concept of multiple documents selection?

Another feature of my version of the code is to try to minimize the number of dialog boxes, but - again - this might not suite what you're code accomplishes.

Thanks for sharing all your good development work. --David

REM {SmartIcon formula to edit field of document selected in view.};
REM {Requires R6+};

REM {2004-05-09 dmp Add file name browsing. Improve error handling.};
REM {2004-05-07 dmp Add features from Matt Holthe of Breaking Par, http://www.breakingpar.com/bkp/home.nsf/Doc!OpenNavigator&87256B280015193F87256E3700680660};
REM {2003-11-20 dmp Handle display of lists and rich text.};
REM {2003-09-02 Dave Lehman, "Set field value/type via smart icon, Version2" http://searchdomino.techtarget.com/search?query=dave+lehman};
REM {2002-12-30 dmp Change list separator to vertical bar. Remember last used field name.};
REM {2001-09-04 Janet Rogers, "Set field value/type via smart icon" http://searchdomino.techtarget.com/search?query=janet+rogers};
REM {2001-04-13 Ken Pespisa, "Change field values from a view" http://searchdomino.techtarget.com/search?query=ken+pespisa};

REM {Get field name.};
field_used_last := @Environment ("SI_FieldEdit_FieldUsedLast");
field_names := @DocFields;
@If ("" = field_names;
@Do (@Prompt ([Ok]; "Canceled"; "No document selected."); @Return (""));
""
);
field_selected := @Prompt ([OkCancelEditCombo]; "Field Edit Selection";
"For document selected in a view:" + @Char (13) +
"select field to change or delete," + @Char (13) +
"or type new field name."; field_used_last; field_names);
REM {Save name of field used last.};
@SetEnvironment ("SI_FieldEdit_FieldUsedLast"; field_selected);

REM {Get old field value.};
old_field_value := @Eval (@Text (field_selected));
REM {Handle possible error value.};
@If (@IsError (old_field_value);
old_field_value := @Text (old_field_value);
""
);
REM {Get current data type.};
old_data_type := @If (
@IsNumber (old_field_value); "Number";
@IsTime (old_field_value); "Date";
"Text"
);

REM {Prepare multi-line/non-text fields for display in prompt.};
old_field_value := @ReplaceSubstring (@Text (old_field_value); @NewLine; " ");

data_types := "DELETE field" : "Canonical name" : "Date" :
"File name" : "Number" : "Password" : "Text";
type_selected := @Prompt ([OkCancelList]:[NoSort]; "Field Data Type";
"Select data type."; old_data_type; data_types);

REM {Get list separator.};
default_separator := @If (
(1 = @Count (old_field_value)) |
@Contains (type_selected; "DELETE" : "File" : "Password");
"None";
@Environment ("SI_FieldEdit_SeparatorUsedLast")
);
separator_choices := "None" : "?" : ";" : "\\" : "|" : "~" : "+";
list_separator := @Prompt ([OkCancelList]:[NoSort]; "List Separator Selection";
"Optional: choose character to separate list values.";
default_separator; separator_choices);
@If ("None" = list_separator;
list_separator := "";
@SetEnvironment ("SI_FieldEdit_SeparatorUsedLast"; list_separator)
);
old_field_value := @Implode (old_field_value; list_separator);

REM {Get new value.};
new_value := @If (
"DELETE field" = type_selected; "";
"Canonical name" = type_selected; @PickList ([Name]);
"File name" = type_selected;
@Prompt ([LocalBrowse]; "File Name Selection"; "3");
"None" = list_separator;
@Prompt ([OkCancelEdit]; "New Value"; "Enter new " + field_selected +
" value."; old_field_value);
@Prompt ([OkCancelEdit]; "New Value"; "Enter new " + field_selected +
" values separated by " + list_separator + " character.";
old_field_value)
);
@If ("None" != list_separator;
new_value := @Explode (new_value; list_separator);
""
);

REM {Use plain text if data conversion fails.};
conversion := @If (
@Contains (type_selected; "Date"); "@TextToTime (";
@Contains (type_selected; "Name"); "@Name ([Canonicalize]; ";
@Contains (type_selected; "Number"); "@TextToNumber (";
@Contains (type_selected; "Password"); "@Password (";
"@Text ("
);
converted_value := @Eval (conversion + "new_value)");
new_value := @If (
"DELETE field" = type_selected; @DeleteField;
@IsError (converted_value); @Do (
@Prompt ([Ok]; "Error"; "Check field for data type error.");
new_value
);
converted_value
);
@SetField (field_selected; new_value)
REM {end}

5 - "Field value is limited to 255 because of the @Prompt limitations"

On this one, could you not simply use a dialog box with a single field on it and return it to the calling form? I have an application in which I am doing this with LS, but a formula implementation would not be difficult and would remove the limitation on characters.

6 - Chad,

I'm not sure if you are aware but Notes formula has a notation for literal lists which applies to text, number and date lists. You just separate values with a colon. So instead of this code.

@If( DataType = @Explode( "Implode;Explode"; ArraySeperator ); ...etc...

You can write

@If( DataType = "Implode" : "Explode" ; ...etc...

Which is more compact and I think easier to read.

This notation applies to many places in the code including the assignment of the DataTypesCombo variable right at the start. No need for the @Explode and all those $ characters.

Jim

PS. Minor point but seperator is spelt separator.

7 - Thanks !!

8 - I was not aware of the speed issue with literal lists so thanks for the education. I am all for performance optimisation when needed but not when it impares code readability for very minimal benefit. I would like to point out that neither of the examples I gave are inside the loop. But I am spliting hairs. You have every right to code this way. I am just trying to point out there are negative consequences of over using a "faster but harder to read" coding pattern, especially when the benefit is so small. The only reason I noticed it was because I was trying to add some new functionality to your code and all those @explodes were confusing the hell out of me so I ran out of time, lost patience, and gave up. Maybe I'll have another go soon.

9 - Thanks Jim for the suggestions. I will correct the address book selection statement that you mentioned.

As for the adding of a basic formula option I have been pondering that for some time, just struggling on the implementation. The execution of just a formula almost fits with the toolbar functions http://www.chadsmiley.com/toolbarFunctions better, but it also edits fields. So the dilemma.

10 - Thanks for the feed back Jim. I was working on some additiona features my self this week. I will consider your thoughts when making my changes.

Just curious what you are looking to add. Maybe everyone could benefit from it. If you would like you can e-mail me.

11 - Yes, I am aware of that feature, and I purposelly avoided it base on Damien's post on Formula's dirty secret (http://damienkatz.net/2004/11/formula-languages-dirty-secret.html).

I would agree that it would make the code easier to read, but my goal is to make this to run as fast as possible since it can run over many documents. Thanks for the suggestion and the spelling correction.

12 - David thanks for the feedback. I wish I could set the field type to Readers, Authors, or Names but Formula does not allow this.

I use the current contents of a field all the time. My favorite is to select multiple documents then move to the document that has the value I want to use then run the macro. This removes any typing mistakes and is less typing.

I did find one feature that I don't have and that is the check to see if a document is selected. I like that. I will also see if any more stream lining can be done with the dialog boxes.