ChadSmiley Blog :: Copy Documents To Database 1.0

Bookmark :

Here is another class that I created to make my life a little easier. Johan Känngård has a much more robust LotusScript list, so does Julian. Everyone has to start somewhere!!!

Public Sub New()
Public Sub getCount()
Public Sub DisplayCount()
Public Sub SelectDatabase()
Public Sub CopySelectedDocument()
Public Sub CopySelectedDocuments()
Public Sub CopyDocuments( collection As NotesDocumentCollection )
Public Sub CopyDocument( doc As NotesDocument )

Copy Documents To Database

Select All

%INCLUDE "LSCONST.LSS
"'/**
'/**
' * A simple way to select multiple Main documents and copy them to a new database
' * This can be used to populate a dev or test environment from production
' *
' *	@author	Chad Schelfhout		http://www.chadsmiley.com/
' *	@version	1.0
' */
Class CopyDocumentsToDatabase
	dbTo As NotesDatabase
	ws As NotesUIWorkspace
	session As NotesSession
	dbFrom As NotesDatabase
	count As Double
	
	'/**
	' * Constructor
	' */
	Public Sub New()
		Set ws = New NotesUIWorkspace
		Set session = New NotesSession
		Set dbFrom = session.CurrentDatabase
	End Sub
	'/**
	' * Returns the number of documents that were copied 
	' */
	Public Function getCount() As Double
		getCount = Count
	End Function
	
	'/**
	' * Displays a prompt informing the user how many documents were updated. 
	' */
	Public Sub DisplayCount()
		Messagebox |Done!

Finished processing | + Cstr(count) + | document(s)| , MB_ICONINFORMATION , "Copy Dcoument(s)"
	End Sub
	
	'/**
	' * Prompts user for a destination database
	' */
	Public Sub SelectDatabase()
		Dim dbSelected As Variant
		dbSelected = ws.Prompt(13 , "" , "" )
		If Isarray( dbSelected ) Then
			Set dbTo = Session.GetDatabase( dbSelected(0) , dbSelected(1) )
		End If
	End Sub
	
	'/**
	' * Determines the destination database and starts the copy process
	' */
	Public Sub CopySelectedDocument()
		Dim Collection As NotesDocumentCollection
		Set collection = dbFrom.UnprocessedDocuments
		If collection.count >= 1 Then
			Call SelectDatabase()
			If Not dbTo Is Nothing Then
				Call CopyDocument( Collection.GetFirstDocument() )
			End If
		End If
	End Sub
	
	'/**
	' * Determines the destination database and starts the copy process
	' */
	Public Sub CopySelectedDocuments
		Dim Collection As NotesDocumentCollection
		Call SelectDatabase()
		Set collection = dbFrom.UnprocessedDocuments
		
		If collection.count <1 Then
			'Messagebox "Sorry, you need to select a document"
			Exit Sub
		Else
			If Not dbTo Is Nothing Then
				Call CopyDocuments( collection ) 
			End If	
		End If
	End Sub
	
	'/**
	' * Cycles through the document collection and copies each to the destination db
	' * Recusion is being used to process all response documents
	' */
	Public Sub CopyDocuments( collection As NotesDocumentCollection )
		Dim docA As NotesDocument
		Set docA = collection.getfirstDocument
		While Not docA Is Nothing 
			Call docA.CopyToDatabase( dbTo )
			Call CopyDocuments( docA.Responses )
			Set docA = collection.getNextDocument(docA)
		Wend
		Count = Count +collection.count
	End Sub
	
	'/**
	' * Copies the document and all of its response to the destination database
	' */
	Public Sub CopyDocument( doc As NotesDocument )
		Call doc.CopyToDatabase( dbTo )
		Call CopyDocuments( doc.Responses )
		Count = Count + 1
	End Sub
End Class