'Domino_Extended: 
 
Option Public
Option Declare
Dim System As Variant
 
'/**
' * A basic class to extend the NotesDocument class to reduce
' * code and improve error checking
' * 
' *	@author	Tim Tripcony				http://www.timtripcony.com
' *	@author	Chad Schelfhout		http://www.chadsmiley.com.previewdns.com/
' * 	
' *	@version	1.0	Created by Tim
' *	@version	1.1	Split intialization, each object is initalized only when it is needed
' * @version	1.2	Converted NotesDocument to NotesDocumentExtended
' * @version	1.3	Converted properties to Function so it is easily ported to Java
' */
Private Class NotesSystem
	'Used to determine if each object has been initalized.
	Private boolSession As Boolean
	Private boolDatabase As Boolean
	Private boolWorkspace As Boolean
	Private boolUIDocument As Boolean
	Private boolDocumentExtended As Boolean
	Private boolName As Boolean
 
	'Possible objects that can be loaded
	Private sessionCurrent As NotesSession
	Private databaseCurrent As NotesDatabase
	Private workspaceCurrent As NotesUIWorkspace
	Private uiDocumentCurrent As NotesUIDocument
	Private documentExtendedCurrent As NotesDocumentExtended
	Private nameCurrent As NotesName	
 
	'/**
	' * Constructor, but nothing else is intialized until it is used.
	' */
	Public Sub New()
		Let boolSession = False
		Let boolDatabase = False
		Let boolWorkspace = False
		Let boolUIDocument = False
		Let boolDocumentExtended = False
		Let boolName = False
	End Sub
 
	'/**
	' * IntializeSession
	' */
	Private Sub intializeSession( )
		If Not boolSession Then
			Set SessionCurrent = New NotesSession()
			Let boolSession = True
		End If
	End Sub
	'/**
	' * Intialize Database
	' */
	Private Sub intializeDatabase( )
		If Not boolDatabase Then
			Call intializeSession()
			Set databaseCurrent = sessionCurrent.CurrentDatabase()
			Let boolDatabase = True
		End If
	End Sub
	'/**
	' * Intialize Document
	' */
	Private Sub intializeDocument( )
		If Not boolDocumentExtended Then
			Call intializeDatabase()
			Set documentExtendedCurrent = New NotesDocumentExtended()
			If isOnServer Then
				Call documentExtendedCurrent.setDocument ( sessionCurrent.DocumentContext() )
			Else
				Call intializeUIDocument()
				If hasUIDocument() Then
					Call documentExtendedCurrent.setDocument( uiDocumentCurrent.Document() )
				End If
			End If
			Let boolDocumentExtended = True
		End If
	End Sub
	'/**
	' * Determines if the object was loaded through the UI
	' */
	Private Function isOnServer () As Boolean
		Call intializeSession()
		Let isOnServer = sessionCurrent.IsOnServer()
	End Function
	'/**
	' * Intialize Workspace
	' */
	Private Sub intializeWorkspace( )
		If Not boolWorkspace Then
			If Not isOnServer Then
'Skip workspace initialization if the code is running on a server because NotesUIWorkspace would be unavailable
				Set workspaceCurrent = New NotesUIWorkspace()
			End If
			Let boolWorkspace = True
		End If
	End Sub
	'/**
	' * Intialize UI Document
	' */
	Private Sub intializeUIDocument( )
		If Not boolUIDocument Then
			If Not isOnServer Then
				Call intializeWorkspace()
				If hasWorkspace() Then
					Set uiDocumentCurrent = workspaceCurrent.CurrentDocument()
				End If
			End If
			Let boolUIDocument = True
		End If
	End Sub	
	'/**
	' * Intialize Name
	' */
	Private Sub intializeName()
		If Not boolName Then
			Call intializeSession()
			Set nameCurrent = New NotesName( sessionCurrent.EffectiveUserName ())
			Let boolName = True
		End If
	End Sub
 
	'/**
	' * Determines if a UI Workspace is available
	' */
	Public Function hasWorkspace() As Boolean
		Call intializeWorkspace()
		Let hasWorkspace = Not workspaceCurrent Is Nothing
	End Function
	'/**
	' * Returns the UI Workspace
	' * @return UI Workspace
	' */
	Public Function ThisWorkspace() As NotesUIWorkspace
		Call intializeWorkspace()
		Set ThisWorkspace = workspaceCurrent
	End Function
	'/**
	' * Returns the current database
	' * @return current database
	' */
	Public Function ThisDatabase() As NotesDatabase
		Call intializeDatabase()
		Set ThisDatabase = databaseCurrent
	End Function
	'/**
	' * determines if there is a current document
	' * @return True/False
	' */
	Public Function hasDocument() As Boolean
		Call intializeDocument()
		Let hasDocument = documentExtendedCurrent.hasDocument()
	End Function
	'/**
	' * Returns the current document
	' * @return current document
	' */
	Public Function ThisDocument() As NotesDocument
		Call intializeDocument()
		Set ThisDocument = documentExtendedCurrent.Document()
	End Function
	'/**
	' * Returns the current ui document
	' * @return current ui document
	' */
	Public Function ThisUIDocument() As NotesUIDocument
		Call intializeDocument()
		Set ThisUIDocument = uiDocumentCurrent
	End Function
	'/**
	' * Determines if a ui document is available
	' * @return True/False
	' */
	Public Function hasUIDocument() As Boolean
		Call intializeUIDocument()
		Let hasUIDocument = Not ( uiDocumentCurrent Is Nothing )
	End Function
	'/**
	' * Returns the current Session
	' * @return current Session
	' */
	Public Function ThisSession() As NotesSession
		Call intializeSession()
		Set ThisSession = sessionCurrent
	End Function
	'/**
	' * Returns the current Users Name object 
	' * @return current user Name object
	' */
	Public Function CurrentUser() As NotesName
		Call intializeName()
		Set CurrentUser = nameCurrent
	End Function
	'/**
	' * Returns the current users common name
	' * @return current users common name
	' */
	Public Function CurrentUserCommon() As String
		Call intializeName()
		Let CurrentUserCommon = nameCurrent.Common
	End Function
	'/**
	' * Returns the current users abbreviated name
	' * @return current users abbreviated name
	' */
	Public Function CurrentUserAbbreviated() As String
		Call intializeName()
		Let CurrentUserAbbreviated = nameCurrent.Abbreviated
	End Function
End Class
 
 
 
'/**
' * A basic class to extend the NotesDocument class to reduce
' * code and improve error checking
' * 
' *	@author	Chad Schelfhout		http://www.chadsmiley.com.previewdns.com/
' *	@version	1.1
' *
' * @history	1.0 Created
' * 					1.1 converted properties to function/subs and ported to Java
' */
Class NotesDocumentExtended
	Private pDoc As NotesDocument
 
	'/**
	' * Constructor
	' */
	Public Sub New()
	End Sub
	'/**
	' * Returns the Values ofthe field if it is availabe
	' * @param fieldName The name of the field on the document
	' * @return the values of the field, or nothing
	' */
	Public Function getFieldValues ( fieldName As String ) As Variant
		Set getFieldValues = Nothing
		If hasDocument() Then
			If pDoc.hasItem( fieldName ) Then
				Let getFieldValues = pDoc.getFirstItem( fieldName).Values
			End If
		End If
	End Function
	'/**
	' * Returns the Values ofthe field if it is availabe
	' * @param fieldName The name of the field on the document
	' * @return the notes item of the field, or nothing
	' */
	Public Function getFieldItem ( fieldName As String ) As NotesItem
		Set getFieldItem = Nothing
		If hasDocument() Then
			If pDoc.hasItem( fieldName ) Then
				Set getFieldItem = pDoc.getFirstItem( fieldName)
			End If
		End If
	End Function
	'/**
	' * Replaces the fields value with the new one supplied
	' * @param fieldName The name of the field on the document
	' * @param Item the new value for the field
	' */
	Public Sub replaceField ( fieldName As String , Var As Variant )
		If hasDocument() Then
			Call pDoc.ReplaceItemValue( fieldName , Var )
		End If
	End Sub
	'/**
	' * Returns the text representation of fields value
	' * @param fieldName The name of the field on the document
	' * @return the fields value as a string
	' */
	Public Function getFieldText ( fieldName As String ) As String
		Let getFieldText = ""
		If hasDocument() Then
			If pDoc.hasItem( fieldName ) Then
				Let getFieldText = pDoc.getFirstItem( fieldName).text
			End If
		End If
	End Function
	'/**
	' * Returns the text representation of fields value as an abstraction
	' * @param fieldName The name of the field on the document
	' * @return the fields value as a string
	' */
	Public Function getFieldAbstraction ( fieldName As String ) As String
		Let getFieldAbstraction = ""
		If hasDocument() Then
			If pDoc.hasItem( fieldName ) Then
				Let getFieldAbstraction = pDoc.getFirstItem( fieldName).abstract( 64994 , False ,False )
			End If
		End If
	End Function
	'/**
	' * Returns the text representation of fields value as unformatted text
	' * @param fieldName The name of the field on the document
	' * @return the fields value as a string
	' */
	Public Function getFieldUnformattedText ( fieldName As String ) As String
		Let getFieldUnformattedText = ""
		If hasDocument() Then
			If pDoc.hasItem( fieldName ) Then
				If ( pDoc.GetFirstItem( fieldName ).Type = RICHTEXT ) Then
					Dim rti As NotesRichTextItem
					Set rti = pDoc.GetFirstItem( fieldName )
					Let getFieldUnformattedText = rti.GetUnformattedText()
				Else
					Let getFieldUnformattedText = getFieldText( fieldName )
				End If
			End If
		End If
	End Function
	'/**
	' * Returns the text representation of fields value as formatted text
	' * @param fieldName The name of the field on the document
	' * @return the fields value as a string
	' */
	Public Function getFieldFormattedText ( fieldName As String , tabstrip As Boolean , lineLength As Integer ) As String
		Let getFieldFormattedText = ""
		If hasDocument() Then
			If pDoc.hasItem( fieldName ) Then
				If ( pDoc.GetFirstItem( fieldName ).Type = RICHTEXT ) Then
					Dim rti As NotesRichTextItem
					Set rti = pDoc.GetFirstItem( fieldName )
					Let getFieldFormattedText = rti.GetFormattedText( tabstrip , lineLength )
				Else
					Let getFieldFormattedText = getFieldText( fieldName )
				End If
			End If
		End If
	End Function
	'/**
	' * Determines if the field exists on the document
	' * @param fieldName The name of the field on the document
	' * @return weather the field exists
	' */
	Public Function hasField ( fieldName As String ) As Boolean
		Let hasField = False
		If hasDocument() Then
			Let hasField = pDoc.hasItem( fieldName )
		End If
	End Function
	'/**
	' * Determines if the field has text. by converting all values to text and checking the length
	' * @param fieldName The name of the field on the document
	' * @return weather the text length is zero
	' */
	Public Function hasFieldText ( fieldName As String ) As Boolean
		Let hasFieldText = False
		If hasDocument() Then
			Let hasFieldText = ( Len( getFieldText( fieldName ) ) > 0 )
		End If
	End Function
	'/**
	' * Determines if a document exists
	' * @return weather there is a document
	' */
	Public Function hasDoc ( ) As Boolean
		Let hasDoc = Not ( pDoc Is Nothing )
	End Function
	'/**
	' * Determines if a document exists
	' * @return weather there is a document
	' */
	Public Function hasDocument ( ) As Boolean
		Let hasDocument = Not ( pDoc Is Nothing )
	End Function
	'/**
	' * Returns the true NotesDocument
	' * @return the NotesDocument
	' */
	Public Sub setDoc ( Doc As NotesDocument )
		Set pDoc = Doc
	End Sub
	'/**
	' * Returns the true NotesDocument
	' * @return the NotesDocument
	' */
	Public Function Doc() As NotesDocument
		Set Doc = pDoc
	End Function
	'/**
	' * Sets the true NotesDocument
	' * @param the NotesDocument
	' */
	Public Sub setDocument ( Document As NotesDocument )
		Set pDoc = Document 
	End Sub
	'/**
	' * Returns the true NotesDocument
	' * @return the NotesDocument
	' */
	Public Function Document As NotesDocument
		Set Document = pDoc
	End Function
End Class
 
 
 
'/**
' * A basic class to extend the NotesDocumentCollection class to reduce
' * navigation issues.  When trying to navigate through documents and deleting
' * some documents the developer trys to navigate to could be deleted
' * this class is intended to remove that possibility.
' * 
' *	@author	Chad Schelfhout		http://www.chadsmiley.com.previewdns.com/
' * 	
' *	@version	1.0	Created
' */
 
Public Class NotesDocumentCollectionExtended
	prevDoc As NotesDocument
	curDoc As NotesDocument
	nxtDoc As NotesDocument
	colDocs As NotesDocumentCollection
 
	Public Sub new()
		Call clear()
	End Sub
	'/**
	' * Clears everything
	' */
	Public Sub clear()
		Set prevDoc = Nothing
		Set curDoc = Nothing
		Set nxtDoc = Nothing
		Set colDocs = Nothing
	End Sub
	'/**
	' * Loads the document collection
	' */
	Public Sub LoadCollection ( docCollection  As NotesDocumentCollection )
		Set colDocs = docCollection
		Call getNavFirst()
	End Sub
	'/**
	' * Navigates to the first document and returns the current document
	' * @return the NotesDocument
	' */
	Public Function getNavFirst () As NotesDocument
		Set prevDoc = Nothing
		If hasCollection Then
			Set curDoc = colDocs.GetFirstDocument
			Set nxtDoc = colDocs.GetNextDocument(curDoc)
		End If
		Set getNavFirst = getCurrentDocument
	End Function
 
	Public Function getNavLast () As NotesDocument
		If hasCollection Then
			Set curDoc = colDocs.GetLastDocument
			Set prevDoc = colDocs.GetPrevDocument(curDoc)
			Set nxtDoc = Nothing
		End If
		Set getNavLast = getCurrentDocument
	End Function
	'/**
	' * Navigates to the next document and returns the current document
	' * @return the NotesDocument
	' */
	Public Function getNavNext () As NotesDocument
		If hasCollection Then
			If hasNextDocument Then
				Set curDoc = nxtDoc
				Call setPrevDocument()
				Call setNextDocument()
			Elseif hasCurrentDocument Then
				Call setPrevDocument()
				Call setNextDocument()
				Set curDoc = Nothing
			End If
		End If
		Set getNavNext = getCurrentDocument
	End Function
	'/**
	' * Navigates to the previous document and returns the current document
	' * @return the NotesDocument
	' */
	Public Function getNavPrev() As NotesDocument
		If hasCollection Then
			If hasPrevDocument Then
				Set curDoc = prevDoc
				Call setPrevDocument()
				Call setNextDocument()
			Elseif hasCurrentDocument Then
				Call setPrevDocument()
				Call setNextDocument()
				Set curDoc = Nothing
			End If
		End If
		Set getNavPrev = getCurrentDocument
	End Function
	'/**
	' * Navigates to the next document if it is available otherwise try the
	' * document after the next until a document is found or the next document is nothing
	' */
	Private Sub setNextDocument() 
		If hasCollection Then
			If hasCurrentDocument Then
				If Not colDocs.GetNextDocument( curDoc ) Is Nothing Then
					If colDocs.GetNextDocument( curDoc ).isDeleted Then
'					Print "Next Document Deleted"
						Set nxtDoc = colDocs.GetNextDocument( nxtDoc ) 
					Else
						Set nxtDoc = colDocs.GetNextDocument( curDoc ) 
					End If
					If hasNextDocument Then
						If nxtDoc.IsDeleted Then
'						Print "Found Deleted document Move next"
							Call setNextDocument() 
						End If
					End If
				Else
					Set nxtDoc = Nothing
				End If
			Else
				Set nxtDoc = Nothing
			End If
		Else
			Set nxtDoc = Nothing
		End If
	End Sub
	'/**
	' * Navigates to the previous document if it is available otherwise try the
	' * document before the previous until a document is found or the previous document is nothing
	' */
	Private Sub setPrevDocument() 
		If hasCollection Then
			If hasCurrentDocument Then
				If Not colDocs.GetPrevDocument( curDoc ) Is Nothing Then
					If colDocs.GetPrevDocument( curDoc ).isDeleted Then
'					Print "Previous Document Deleted"
						Set prevDoc = colDocs.GetPrevDocument( prevDoc ) 
					Else
						Set prevDoc = colDocs.GetPrevDocument( curDoc ) 
					End If
					If hasPrevDocument Then
						If prevDoc.IsDeleted Then
'						Print "Found Deleted document Move previous"
							Call setPrevDocument() 
						End If
					End If
				Else
					Set prevDoc = Nothing
				End If
			Else
				Set prevDoc = Nothing
			End If
		Else
			Set prevDoc = Nothing
		End If
	End Sub
	'/**
	' * Returns the current document
	' * @return the NotesDocument
	' */
	Public Function getCurrentDocument() As NotesDocument
		Set getCurrentDocument = curDoc
	End Function
	'/**
	' * Returns the previous document
	' * @return the NotesDocument
	' */
	Public Function getPrevDocument() As NotesDocument
		Set getPrevDocument = prevDoc
	End Function
	'/**
	' * Returns the next document
	' * @return the NotesDocument
	' */
	Public Function getNextDocument() As NotesDocument
		Set getNextDocument = nxtDoc
	End Function
	'/**
	' * Returns weather the current document exists
	' * @return the True/False
	' */
	Public Function hasCurrentDocument() As Boolean
		Let hasCurrentDocument = Not curDoc Is Nothing
	End Function
	'/**
	' * Returns weather the next document exists
	' * @return the True/False
	' */
	Public Function hasNextDocument() As Boolean
		Let hasNextDocument = Not nxtDoc Is Nothing
	End Function
	'/**
	' * Returns weather the previous document exists
	' * @return the True/False
	' */
	Public Function hasPrevDocument() As Boolean
		Let hasPrevDocument = Not prevDoc Is Nothing
	End Function
	'/**
	' * Returns weather a collection exists
	' * @return the True/False
	' */
	Public Function hasCollection() As Boolean
		Let hasCollection = Not colDocs Is Nothing
	End Function
End Class